使 D 成为我最喜欢的编程语言的特性

UFCS 使您能够编写具有自然流程的可重用代码，而不会牺牲便利性。

早在 2017 年，我就写过为什么 D 编程语言是开发的绝佳选择。但是 D 中有一个突出的特性我没有充分展开：通用函数调用语法 (UFCS)。 UFCS 是 D 中的一种语法糖，它允许像类型的成员函数一样链接类型（字符串、数字、布尔值等）上的任何常规函数。

如果您尚未安装 D，请安装 D 编译器，以便您可以运行 D 代码在本文中亲自尝试。

考虑以下示例代码

// file: ufcs_demo.d

module ufcs_demo;

import std.stdio : writeln;

int[] evenNumbers(int[] numbers)
{
    import std.array : array;
    import std.algorithm : filter;

    return numbers.filter!(n => n % 2 == 0).array;
}

void main()
{
    writeln(evenNumbers([1, 2, 3, 4]));
}

使用您最喜欢的 D 编译器编译它，看看这个简单的示例应用程序做了什么

$ dmd ufcs_demo.d
$ ./ufcs_demo
[2, 4]

但是，借助 UFCS 作为 D 的内置功能，您也可以以自然的方式编写代码

...
writeln([1, 2, 3, 4].evenNumbers());
...

或者完全删除现在多余的括号，使其感觉像 evenNumbers 是一个属性

...
writeln([1, 2, 3, 4].evenNumbers); // prints 2, 4
...

所以完整的代码现在变成

// file: ufcs_demo.d

module ufcs_demo;

import std.stdio : writeln;

int[] evenNumbers(int[] numbers)
{
    import std.array : array;
    import std.algorithm : filter;

    return numbers.filter!(n => n % 2 == 0).array;
}

void main()
{
    writeln([1, 2, 3, 4].evenNumbers);
}

使用您最喜欢的 D 编译器编译并试用。正如预期的那样，它产生相同的输出

$ dmd ufcs_demo.d
$ ./ufcs_demo
[2, 4]

在编译期间，编译器自动将数组作为函数的第一个参数放置。这是一种常见的模式，使 D 的使用如此令人愉快，因此它非常符合您对代码的自然思考方式。结果是函数式编程。

您可能可以猜到这将打印什么

//file: cool.d
import std.stdio : writeln;
import std.uni : asLowerCase, asCapitalized;

void main()
{
    string mySentence = "D IS COOL";
    writeln(mySentence.asLowerCase.asCapitalized);
}

但只是为了确认