D 语言让我爱不释手的特性

UFCS 赋予你能力去组合可重用的代码，它拥有自然的流程且不牺牲便利性。

早在 2017 年，我就写过一篇关于为什么 D 编程语言是开发的绝佳选择的文章。但是 D 语言中有一个突出的特性我没有充分展开讨论：通用函数调用语法 (UFCS)。UFCS 是 D 语言中的一种语法糖，它允许像调用类型的成员函数一样链式调用任何类型的常规函数（字符串、数字、布尔值等）。

如果你还没有安装 D 语言，安装 D 编译器，以便你可以运行本文中的 D 代码。

考虑以下示例代码

// file: ufcs_demo.d

module ufcs_demo;

import std.stdio : writeln;

int[] evenNumbers(int[] numbers)
{
    import std.array : array;
    import std.algorithm : filter;

    return numbers.filter!(n => n % 2 == 0).array;
}

void main()
{
    writeln(evenNumbers([1, 2, 3, 4]));
}

使用你最喜欢的 D 编译器编译这段代码，看看这个简单的示例应用程序的作用

$ dmd ufcs_demo.d
$ ./ufcs_demo
[2, 4]

但是，借助作为 D 语言内置特性的 UFCS，你也可以用自然的方式编写代码

...
writeln([1, 2, 3, 4].evenNumbers());
...

或者完全删除现在变得多余的括号，使其感觉 evenNumbers 像一个属性

...
writeln([1, 2, 3, 4].evenNumbers); // prints 2, 4
...

所以完整的代码现在变成

// file: ufcs_demo.d

module ufcs_demo;

import std.stdio : writeln;

int[] evenNumbers(int[] numbers)
{
    import std.array : array;
    import std.algorithm : filter;

    return numbers.filter!(n => n % 2 == 0).array;
}

void main()
{
    writeln([1, 2, 3, 4].evenNumbers);
}

使用你最喜欢的 D 编译器编译并试用它。正如预期的那样，它产生相同的输出

$ dmd ufcs_demo.d
$ ./ufcs_demo
[2, 4]

在编译期间，编译器自动地将数组作为函数的第一个参数放置。这是一种常见的模式，使得使用 D 语言成为一种乐趣，因为它非常符合你对代码的自然思考方式。结果就是函数式编程风格。

你可能可以猜到这会打印什么

//file: cool.d
import std.stdio : writeln;
import std.uni : asLowerCase, asCapitalized;

void main()
{
    string mySentence = "D IS COOL";
    writeln(mySentence.asLowerCase.asCapitalized);
}

但为了确认一下