D 语言使我着迷的特性

UFCS 使您能够编写可重用代码，该代码具有自然的流程，而又不牺牲便利性。

早在 2017 年，我就写过一篇关于为什么 D 编程语言是开发的绝佳选择的文章。但是 D 语言中有一个突出的特性我没有充分展开：通用函数调用语法 (UFCS)。 UFCS 是 D 语言中的一种语法糖，它使您能够像类型的成员函数一样，在类型（字符串、数字、布尔值等）上链接任何常规函数。

如果您尚未安装 D，请安装 D 编译器，以便您可以自己运行本文中的 D 代码。

考虑以下示例代码

// file: ufcs_demo.d

module ufcs_demo;

import std.stdio : writeln;

int[] evenNumbers(int[] numbers)
{
    import std.array : array;
    import std.algorithm : filter;

    return numbers.filter!(n => n % 2 == 0).array;
}

void main()
{
    writeln(evenNumbers([1, 2, 3, 4]));
}

使用您最喜欢的 D 编译器编译它，看看这个简单的示例应用程序的功能

$ dmd ufcs_demo.d
$ ./ufcs_demo
[2, 4]

但是，借助 UFCS 作为 D 的内置特性，您也可以以自然的方式编写代码

...
writeln([1, 2, 3, 4].evenNumbers());
...

或者完全删除现在多余的括号，使其感觉就像 evenNumbers 是一个属性

...
writeln([1, 2, 3, 4].evenNumbers); // prints 2, 4
...

因此，完整的代码现在变为

// file: ufcs_demo.d

module ufcs_demo;

import std.stdio : writeln;

int[] evenNumbers(int[] numbers)
{
    import std.array : array;
    import std.algorithm : filter;

    return numbers.filter!(n => n % 2 == 0).array;
}

void main()
{
    writeln([1, 2, 3, 4].evenNumbers);
}

使用您最喜欢的 D 编译器编译并试用。正如预期的那样，它产生相同的输出

$ dmd ufcs_demo.d
$ ./ufcs_demo
[2, 4]

在编译期间，编译器自动将数组作为函数的第一个参数放置。这是一种常规模式，使使用 D 成为一种乐趣，因此它非常符合您对代码的自然思考方式。结果是函数式编程风格。

您可能可以猜到这会打印什么

//file: cool.d
import std.stdio : writeln;
import std.uni : asLowerCase, asCapitalized;

void main()
{
    string mySentence = "D IS COOL";
    writeln(mySentence.asLowerCase.asCapitalized);
}

但只是为了确认